home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Loadstar 2
/
002.d81
/
mc tester
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-08-26
|
4KB
|
113 lines
10 poke53272,21:poke783,peek(783)and254
20 poke53280,5:poke53281,1:printchr$(31)
30 goto180
40 poke781,6:poke782,0:sys65520
50 forx=1to640:print" ";:next:return
180 printchr$(147)
190 poke781,5:poke782,8:sys65520:print"multiple choice tester"
200 poke781,8:poke782,19:sys65520:print"by"
205 poke781,11:poke782,14:sys65520:print"donna k. woody"
210 poke781,23:poke782,3:sys65520:print"would you like instructions (y/n)?[160]";:
220 poke198,0:wait198,1:geta$:ifa$<>"y"anda$<>"n"then220
230 ifa$="y"thengosub5000
240 printchr$(147)
241 print"enter test file name":print"(x to exit)"
242 input fi$:iffi$="x"then810
243 iflen(fi$)<1then240
244 gosub10000:ifcz=62then242
245 poke781,10:poke782,0:sys65520:print"please wait......."
247 print:print"loading file......."
250 open4,8,4,"0:"+fi$+",seq,read"
270 input#4,nu
275 dimw$(nu),s1$(nu),s2$(nu),s3$(nu),an$(nu)
280 fori=1tonu
290 input#4,w$(i),s1$(i),s2$(i),s3$(i),an$(i)
300 nexti
310 close4
311 r=o:i=0
312 fori=1tonu
314 printchr$(147):printtab(8)"multiple choice tester"
315 printchr$(19):poke781,2:poke782,33:sys65520:printr"/"i
332 poke781,4:poke782,13:sys65520:print"question #"i:print
334 printw$(i):print
340 print"a. "s1$(i):print
350 print"b.[160]"s2$(i):print
360 print"c. "s3$(i):print
370 print:print" -->[160]";
380 poke198,0:wait198,1:geta$:printa$
385 ifa$<>"a"anda$<>"b"anda$<>"c"then380
430 printchr$(144)
432 ifa$=an$(i)thenwr$="right!!!"
434 ifa$<>an$(i)thenwr$="wrong."
436 poke781,18:poke782,10:sys65520:print" [157][157][157][157][157][157][157][157][157][157]"wr$
440 ifa$=an$(i)then485
480 poke781,20:poke782,0:sys65520:print"correct answer is "an$(i)
485 ifa$=an$(i)thenr=r+1
490 ifa$<>an$(i)thenprint""
492 printchr$(31)
500 poke781,23:poke782,1:sys65520:print"press space bar to continue.";:
510 poke198,0:wait198,1:geta$:ifa$<>" "then510
520 poke781,18:poke782,10:sys65520:print" "
530 nexti
600 printchr$(147):printtab(8)"multiple choice tester"
605 pc=int((r/nu)*100)
610 ifpc>=90thenprintchr$(144)
620 poke781,3:poke782,0:sys65520:print"90% - 100% -- excellent! ":printchr$(31)
630 ifpc>=70andpc<90thenprintchr$(144)
640 poke781,5:poke782,0:sys65520:print"70% - 80% -- very good!":printchr$(31)
650 ifpc>=60andpc<70thenprintchr$(144)
660 poke781,7:poke782,0:sys65520:print"60% - 70% -- fair":printchr$(31)
680 ifpc>=50andpc<60thenprintchr$(144)
690 poke781,9:poke782,0:sys65520:print"50% - 60% -- not too good"
700 printchr$(31)
710 ifpc<50thenprintchr$(144)
720 poke781,11:poke782,0:sys65520:print" 0% - 50% -- we know you didn't cheat"
730 printchr$(31)
810 poke781,20:poke782,0:sys65520:iffi$="x"then820
815 print"press <r> to repeat the test."
820 print"press <m> to go back to loadstar.":print"press <a> for another test."
830 poke198,0:wait198,1:geta$:ifa$<>"r"anda$<>"m"anda$<>"a"then830
840 ifa$="r"thenprintchr$(147):goto311
845 ifa$="a"thenprintchr$(147):clr:goto240
850 ifa$="m"thenprintchr$(147):goto63000
5000 rem * instructions
5010 fori=1to2
5015 printchr$(147)
5020 forj=1to9
5030 reada$:printa$:print
5040 nextj
5050 poke781,23:poke782,6:sys65520:print"press space bar to continue";
5060 poke198,0:wait198,1:geta$:ifa$<>" "then5060
5070 nexti
5080 return
6000 data" this program will help you review or"
6005 data"learn any subject you want. you can"
6007 data"create multiple choice test files"
6010 data"using the 'mc test maker' program."
6012 data"then just enter the correct file name"
6015 data"when asked for it in this program"
6020 data"and review the subject you want."
6022 data" after answering the question, you"
6025 data"will be told if you were right or wrong"
6030 data"and will be given the correct answer."
6032 data" your score is shown in the upper"
6035 data"right-hand corner. after the test is"
6037 data"over, you will be given a score based"
6040 data"on the number of questions you answered"
6042 data"correctly. answers are entered with a"
6045 data"single keystroke. you do not need to"
6050 data"press the <return> key."
6052 data" have fun and good luck!"
10000 open15,8,15
10010 open4,8,4,"0:"+fi$+",seq,read":close4
10015 input#15,cz,mz$,sz,tz:close15
10020 ifcz=0thenreturn
10030 ifcz=62thenprintchr$(147):print"that file does not exist on this disk."
10040 print:print:print"do you want to continue (y/n)?[160]";:poke198,0:wait198,1:geta$:printa$
10050 ifa$="y"thenprintchr$(147):return
10060 ifa$="n"thenprintchr$(147):goto63000
10070 print"[145][145][145][145]":goto10040
63000 print"[147]load"chr$(34)"payload"chr$(34)",8":print"run"
63010 poke631,13:poke632,13:poke198,2
63020 end